Code Samples By Category

Obtaining General Network Information

Display current server name, domain name, and user name.

<HTML>
<BODY>

<%
' Display Current Server, Domain and User Names
Set AU = Server.CreateObject("Persits.AspUser")
%>

Server: <B><% = AU.GetComputerName %></B><BR>
Domain: <B><% = AU.GetDomainName %></B><BR>
User: <B><% = AU.GetUserName %></B><BR>

</BODY>
</HTML>

Display the Primary Domain Controller (PDC) of the current domain.

<HTML>
<BODY>

<%
' Display Primary Domain Controller of the current domain
Set AU = Server.CreateObject("Persits.AspUser")
%>

Primary Domain Controller: <B><% = AU.DomainController %></B>

</BODY>
</HTML>

Account Impersonation

Impersonate an NT user account so that all the following commands on that page run in the security context of that account.

Validate a username and password against NT Security Account Manager (SAM) database.

<%
' Validate a username/password against SAM

Set AU = Server.CreateObject("Persits.AspUser")
On Error Resume Next
AU.LogonUser "mydomain", "Administrator", "xxxx"
If Err <> 0 Then Response.Redirect "AccessDenied.html"

' Cancel "On Error Resume Next"
On Error Goto 0
%>

<HTML>
<BODY>

Account is validated.

</BODY>
</HTML>

User and Group Enumeration

Rename a given user.

Create a drop-down list of domain user accounts on a given domain.

Enumerate all local and domain groups on a given server.

<HTML>
<BODY>

<%
' Enumerate local and domain groups on a given server

Set AU = Server.CreateObject("Persits.AspUser")
AU.Server = "\\myserver"
%>

<B>Local Groups:</B><BR>
<BLOCKQUOTE>
<% For Each Group in AU.LocalGroups %>
<% = Group.Name %><BR>
<% Next %>
</BLOCKQUOTE>
<P>
<B>Domain Groups:</B><BR>
<BLOCKQUOTE>
<% For Each Group in AU.Groups %>
<% = Group.Name %><BR>
<% Next %>
</BLOCKQUOTE>

</BODY>
</HTML>

Is this name a user or group?

Browsing and Setting User and Group Properties

Rename a given user.

Set the "User Must Change Password at Next Logon" property for a given user.

Set Comment property of a given local group.

Allow a user to change his/her password.

<HTML>
<BODY>

<% ' Allow a user to change their password.
' This page must be protected by Basic Authentication

UserName = Request.ServerVariables("LOGON_USER")
If UserName = "" Then
   Response.Write "<h2>You must disable anonymous access for this sample to function.</h2>"
   Response.End
End If

If Request("ChangePassword") <> "" Then
   If Request("Pass1") <> Request("Pass2") Then
      Response.Write("The new password was not correctly confirmed.<HR>")
   Else
      Set AU = Server.CreateObject("Persits.AspUser")
      AU.ChangePassword "", UserName, Request("OldPass"), Request("Pass1")
      Response.Write("Password has been changed.<HR>")
   End If
End If
%>

<H1>User: <% = UserName %></h1>

<TABLE>
<FORM Action="test1.asp" METHOD=POST>
<TD>Old Password:</TD> <TD><INPUT SIZE=40 TYPE=PASSWORD NAME="OldPass"><TD><TR>
<TD>New Password:</TD> <TD><INPUT SIZE=40 TYPE=PASSWORD NAME="Pass1"><TD><TR>
<TD>Confirm Password:</TD> <TD><INPUT SIZE=40 TYPE=PASSWORD NAME="Pass2"><TD><TR>
<INPUT TYPE=HIDDEN NAME=ChangePassword VALUE=1>
<INPUT TYPE=SUBMIT VALUE="Change">
</FORM>
</TABLE>

</BODY>
</HTML>

User and Group Creation and Deletion

Add a new local user account interactively.

<HTML>
<BODY>

<%
' Add a user interactively (similar to NT User Manager)

Set AU = Server.CreateObject("Persits.AspUser")
AU.LogonUser "MYDOMAIN", "Administrator", "xxxxxxx"

If Request("Save") <> "" Then
   If Request("Pass1") <> Request("Pass2") Then
      Response.Write("The new password was not correctly confirmed.<HR>")
      Response.End
   End If

   Set NewUser = AU.AddLocalUser( Request("Name"), Request("Pass1"), Request("Comment") )

   NewUser.FullName = Request("FullName")
   NewUser.HomeDir = Request("HomeDir")
   NewUser.MustChangePassword = (Request("Must") <> "")
   NewUser.CannotChangePassword = (Request("Cannot") <> "")
   NewUser.PasswordNeverExpires = (Request("Never") <> "")
   NewUser.AccountDisabled = (Request("Disabled") <> "")
   NewUser.SetInfo

   Response.Write("<b>User added.</b><HR>")
End If

%>
<H1>User Properties</H1>

<TABLE>
<FORM Action="thisfilename.asp" METHOD=POST>
<TD>User Name:</TD><TD><INPUT SIZE=40 TYPE=TEXT NAME="Name"></TD><TR>
<TD>Full Name:</TD><TD><INPUT SIZE=40 TYPE=TEXT NAME="FullName"><TD><TR>
<TD>Description:</TD><TD><INPUT SIZE=40 TYPE=TEXT NAME="Comment"><TD><TR>
<TD>Home Dir:</TD><TD><INPUT SIZE=40 TYPE=TEXT NAME="HomeDir"><TD><TR>

<TD>Password:</TD><TD><INPUT SIZE=40 TYPE=PASSWORD NAME="Pass1"><TD><TR>
<TD>Confirm Password:</TD><TD><INPUT SIZE=40 TYPE=PASSWORD NAME="Pass2"><TD><TR>
</TABLE>
<HR>
<INPUT TYPE=CHECKBOX NAME=Must VALUE=1 CHECKED>
User Must Charge Password at Next Login<BR>

<INPUT TYPE=CHECKBOX NAME=Cannot VALUE=1>
User Cannot Change Password<BR>

<INPUT TYPE=CHECKBOX NAME=Never VALUE=1>
Password Never Expires<BR>

<INPUT TYPE=CHECKBOX NAME=Disabled VALUE=1>
Account Disabled<BR>

<INPUT TYPE=HIDDEN NAME=Save VALUE=1>
<BR>
<INPUT TYPE=Submit VALUE="Add user">
</FORM>

</BODY>
</HTML>

Add a new Domain group.

Delete a given local user and group.

Managing User and Group Membership

Assign a given user to the Account Operators group.

Add a new domain user and change the Primary Group to Domain Admins.

<HTML>
<BODY>

<%
' Create a domain user and change its Primary Group to "Domain Admins"

Set AU = Server.CreateObject("Persits.AspUser")
AU.LogonUser "MYDOMAIN", "Administrator", "xxxxxx"
Set User = AU.AddUser("My New User", "xxxx", "some comment")
User.AddToGroup "Domain Admins", True ' because it is a global group
User.PrimaryGroupID = DOMAIN_GROUP_RID_ADMINS
User.SetInfo
%>

</BODY>
</HTML>

Add an existing user to an existing global group, and set this user's Primary Group to this group.

Remove a given user from a given global group.

Is this domain user a Domain Admin?

Does the Domain Admins group include a given user?

Add a domain member to the given local group.

List all members of a given local group.

List all groups a given user belongs to.

<HTML>
<BODY>

<%
' List all groups a user belongs to

Set AU = Server.CreateObject("Persits.AspUser")

Set User = AU.Users("peter")

Response.Write "<B>Global Groups:</B><BR>"
For Each Group in User.Groups
Response.Write Group & "<BR>"
Next

Response.Write "<P><B>Local Groups:</B><BR>"
For Each Group in User.LocalGroups
Response.Write Group & "<BR>"
Next
%>

</BODY>
</HTML>

Network Browsing

List all machines visible from the local server with all properties.

<HTML>
<BODY>

<% 'List all machines visible from the local server with all properties. %>
<% Set AU = Server.CreateObject("Persits.AspUser") %>

<h1>Server List</h1>

<TABLE BORDER=1 CELLSPACING=0 CELLPADDING=2>
<TH>Server</TH>
<TH>IsSQLServer</TH>
<TH>IsPDC</TH>
<TH>IsBDC</TH>
<TH>IsTimeSource</TH>
<TH>IsAFP</TH>
<TH>IsNovell</TH>
<TH>IsDomainMember</TH>
<TH>IsLocalListOnly</TH>
<TH>IsPrint</TH>
<TH>IsDialin</TH>
<TH>IsXenix</TH>
<TH>IsMFPN</TH>
<TH>IsNT</TH>
<TH>IsWFW</TH>
<TH>IsNTServer</TH>
<TH>IsPotentialBrowser</TH>
<TH>IsBackupBrowser</TH>
<TH>IsMasterBrowser</TH>
<TH>IsDomainMasterBrowser</TH>
<TH>IsDomainEnum</TH>
<TH>IsWindows</TH><TR>
<% For Each Srv in AU.Servers %>
<TD><% = Srv %></TD>
<TD><% If Srv.IsSQLServer Then Response.Write "X"%> </TD>
<TD><% If Srv.IsPDC Then Response.Write "X"%> </TD>
<TD><% If Srv.IsBDC Then Response.Write "X"%> </TD>
<TD><% If Srv.IsTimeSource Then Response.Write "X"%> </TD>
<TD><% If Srv.IsAFP Then Response.Write "X"%> </TD>
<TD><% If Srv.IsNovell Then Response.Write "X"%> </TD>
<TD><% If Srv.IsDomainMember Then Response.Write "X"%> </TD>
<TD><% If Srv.IsLocalListOnly Then Response.Write "X"%> </TD>
<TD><% If Srv.IsPrint Then Response.Write "X"%> </TD>
<TD><% If Srv.IsDialin Then Response.Write "X"%> </TD>
<TD><% If Srv.IsXenix Then Response.Write "X"%> </TD>
<TD><% If Srv.IsMFPN Then Response.Write "X"%> </TD>
<TD><% If Srv.IsNT Then Response.Write "X"%> </TD>
<TD><% If Srv.IsWFW Then Response.Write "X"%> </TD>
<TD><% If Srv.IsNTServer Then Response.Write "X"%> </TD>
<TD><% If Srv.IsPotentialBrowser Then Response.Write "X"%> </TD>
<TD><% If Srv.IsBackupBrowser Then Response.Write "X"%> </TD>
<TD><% If Srv.IsMasterBrowser Then Response.Write "X"%> </TD>
<TD><% If Srv.IsDomainMasterBrowser Then Response.Write "X"%> </TD>
<TD><% If Srv.IsDomainEnum Then Response.Write "X"%> </TD>
<TD><% If Srv.IsWindows Then Response.Write "X"%> </TD>
<TR>
<% Next %>
</TABLE>

</BODY>
</HTML>

Display the Maximum Password Age specified in the Account Policy of the PDC.

File and Directory Permission Management

Give a user "Full Control" to a given file or directory.

<HTML>
<BODY>

<%
' Give a user Full Control to a file or directory
Set AU = Server.CreateObject("Persits.AspUser")
Set File = AU.File("d:\somefile.txt")
File.AllowAccess "peter", GENERIC_ALL

%>

</BODY>
</HTML>

Give Everyone Read (RX) control to a given file or directory.

<HTML>
<BODY>

<%
' Give Everyone "Read" (RX) access to a file
Set AU = Server.CreateObject("Persits.AspUser")
AU.LogonUser "MYDOMAIN", "Administrator", "xxxxx"
Set File = AU.File("d:\somefile.txt")

File.AllowAccess "Everyone", GENERIC_READ + FILE_GENERIC_EXECUTE

%>

</BODY>
</HTML>

Revoke a permission previously given to a user.

Deny a given user any access to a file.

<HTML>
<BODY>

<%
' Deny a user any access to a file
Set AU = Server.CreateObject("Persits.AspUser")
AU.LogonUser "MYDOMAIN", "Administrator", "xxxxxx"
Set File = AU.File("d:\somefile.txt")

File.DenyAccess "Guest", GENERIC_ALL
%>

</BODY>
</HTML>

Display all permission entries for a given file.

<HTML>
<BODY>

<%
' Display all permissions for a file

Set AU = Server.CreateObject("Persits.AspUser")
Set File = AU.File("d:\somefile.txt")

For i = 1 to File.DenialCount
   Set Ace = File.GetDenialAce(i)
   Response.Write Ace.AccountName & " -- No Access<br>"
Next

For i = 1 to File.AllowanceCount
   Set Ace = File.GetAllowanceAce(i)
   Response.Write Ace.AccountName & " -- "

   If Ace.CheckFlag(FILE_READ_DATA) Then Response.Write "R"
   If Ace.CheckFlag(FILE_WRITE_DATA) Then Response.Write "W"
   If Ace.CheckFlag(FILE_EXECUTE) Then Response.Write "X"
   If Ace.CheckFlag(DELETE) Then Response.Write "D"
   If Ace.CheckFlag(WRITE_DAC) Then Response.Write "P"
   If Ace.CheckFlag(WRITE_OWNER) Then Response.Write "O"

   Response.Write "<BR>"
Next

%>

</BODY>
</HTML>

Make a given file hidden and read-only.

<HTML>
<BODY>

<%
' Make a file hidden and read-only
Set AU = Server.CreateObject("Persits.AspUser")
Set File = AU.File("d:\somefile.txt")

File.Attributes = File.Attributes + FILE_ATTRIBUTE_READONLY + FILE_ATTRIBUTE_HIDDEN
%>

</BODY>
</HTML>

Set Comment property of a given local group.

Advanced Error Handling

Add a user to a group. Ignore "User already belongs to that group" error.

<HTML>
<BODY>

<%
' Add a user to a group. Ignore "User already belongs to that group" error

Set AU = Server.CreateObject("Persits.AspUser")
AU.IncludeErrorCode = True ' prefix all error message with genuine NT error codes
AU.LogonUser "MYDOMAIN", "Administrator", "xxxxxx"
Set User = AU.Users("peter")

On Error Resume Next
User.AddToGroup "Domain Guests"

If Left(Err.Description, 4) <> "08BC" Then ' Ignore NERR_UserInGroup
Response.Write Mid(Err.Description, 6) ' skip error code prefix
End If

On Error Goto 0 ' Cancel error trapping
%>

</BODY>
</HTML>